Making an install routine for Notes 8

In order to install Lotus Notes 8 in the organisation, we plan to use both LAN and CDs. People will come to a short course, bringing their laptop with them, and while the users gets their info about the new version, we install it for them right away.

Installing 8.0.2 is pretty straight forward, but we discovered an error in the install point of the existing Notes 7 client which forces us to do a few tricks with the registry before we start to install the new version. The issue is caused by a reference in the registry to a CD drive where the notes7 source files was supposed to be stored. The install program will search for this directory during the upgrade process in order to uninstall notes 7, and since it can't find anything the process stops.

We will have to fix that with the help of a "negative" .REG file, which will remove all the Notes 7 stuff from the registry. Likewise, since we do not have the option to uninstall Notes 7 the normal way, we will have to do the file clean-up manually.

The rest of the stuff is pretty straightforward:

The .EXE file containing the 8.0.2 client was unpacked to a directory using WinZip

We made a few changes to the /deploy/extras/presetfeeds.opml in order to distribute a few extra RSS feeds

Made a copy of the original .MSI file, and the /deploy/install.xml file, but decided not to alter anything. The default configuration was what we wanted anyway.

And finally, here's the batch file:

@echo off
TITLE INSTALL LOTUS NOTES 8.x CLIENTS
SET SOURCEDIR=\INSTALL\NOTES\NOTES.802
SET MSIFILE=nd802.msi
REM SET CORRECT DRIVE LETTER.
REM THIS ROUTINE MAKES IT POSSIBLE TO USE THIS ON CD AS WELL
FOR %%i IN (F G H I J K L M N O P Q R S T U V W X Y Z C D E) DO IF EXIST %%i:%SOURCEDIR%\%MSIFILE% SET CDROM=%%i:
SET NOTES7=NONE
%CDROM%
CD %SOURCEDIR%
IF NOT EXIST %SOURCEDIR%\%MSIFILE% GOTO :ERRORTRAPPING
REM ======== CHECK IF NOTES IS PRESENT =============
IF EXIST C:\LOTUS\NOTES\NOTES.EXE SET NOTESCLIENT=TRUE
REM ======== CHECK IF NOTES7 IS PRESENT =============
IF EXIST C:\Lotus\notes\JVM\JAVADOCS.ZIP SET NOTES7=YES
REM ======= CHECK IF LOTUS FILES ARE PRESENT
REM ======= IF NOTES.INI IS PLACED IN PROGRAM DIR, MOVE IT TO DATADIR
IF EXIST C:\LOTUS\NOTES\NOTES.INI COPY C:\LOTUS\NOTES\NOTES.INI C:\LOTUS\NOTES\DATA\NOTES.INI
REM ==== IF CLIENT IS PRESENT, COPY NECESSARY FILES FOR KILLING CLIENT PROCESSES (BEFORE INSTALLING)WE COPY THEM EVEN IF THE NSD.EXE ALREADY IS THERE
IF "%NOTES7%" EQU "YES" COPY %CDROM%%SOURCEDIR%\UTIL\*.* C:\LOTUS\NOTES
IF NOT EXIST C:\LOTUS\NOTES\NSD.EXE GOTO :VIDERE
REM ===== STOP ALL CURRENT NOTES PROCESSES
C:
CD C:\LOTUS\NOTES\DATA
..\NSD.EXE -kill
REM ==== DELETE FAULTY REGISTRY VALUES CAUSED BY ZENWORKS INSTALL
IF "%NOTES7%" EQU "YES" REGEDIT -s %CDROM%%SOURCEDIR%\UTIL\ND8INST1.REG
REM ==== DELETE ALL FILES IN PROGDIR
CD C:\LOTUS\NOTES
DEL /Q c:\lotus\notes\*.*
DEL /Q c:\lotus\notes\data\names.nt*
IF EXIST C:\LOTUS\NOTES\JVM\JAVADOCS.ZIP DELETE /Y C:\LOTUS\NOTES\JVM\JAVADOCS.ZIP
:VIDERE
REM ==== INSTALL THE NOTES 8 CLIENT
%CDROM%
CD %SOURCEDIR%
%MSIFILE% /qb PROGDIR="C:\Lotus\notes\" DATADIR="C:\Lotus\notes\Data\"
GOTO :SLUTT
:ERRORTRAPPING
Echo ERROR
:SLUTT